root/ocaml-remix/trunk/layer.ml

(** a layer consists of a list of sounds with start times and lengths, and
    a transparency list (nb: default transparency is 0.0) *)
type layer = {mutable la_notes:(Time.extent * Note.note) list;
              mutable la_transparency:
              (Time.extent * Transparency.transparency) list};;

exception OverlappingSounds;;

let empty () = {la_notes=[]; la_transparency=[]};;

let add_note layer plugin extent =
  layer.la_notes <- (extent, plugin)::layer.la_notes;;

let add_transparency layer trans extent =
  layer.la_transparency <- (extent, trans)::layer.la_transparency;;

let transparency_list layer = layer.la_transparency;;

let print layer = 
  let rec _print_sounds l = match l with
    | ((start, length), sound)::t -> (
            Printf.printf "\tplugin from %s len %s\n" 
                              (Time.to_string start) (Time.to_string length);
            _print_sounds t)
    | [] -> () in
  let rec _print_transparencies t = match t with
    | ((start, length), trans)::r -> (
            Printf.printf "\ttrans from %s len %s\n"
                              (Time.to_string start) (Time.to_string length);
            _print_transparencies r)
    | [] -> () in
  Printf.printf "layer is:\n"; 
  _print_sounds layer.la_notes;
  _print_transparencies layer.la_transparency;;

(*
 * for each sound: 
 *
 * <-------sound-------->
 *           <----------render-------->
 * raw_start + raw_length > raw_render_start,
 * raw_render_start + raw_render_length > raw_start
 *
 *                  <----------sound----->
 * <----------render------------>
 * still true
 * 
 * <-----sound--->   <----render---->
 * raw_start + raw_length > raw_render_start is FALSE
 *
 * <----render---->    <----sound--->
 * raw_render_start + raw_render_length > raw_start is FALSE
 *
 * -------
 *
 * <------sound------->
 *          <----render---->
 *)
let to_note layer undersound remix _ render_extent =
  let (raw_render_start, raw_render_length) = 
      Time.extent_to_raw_time remix render_extent in
  let sound = FB.create raw_render_length (Remix.channels remix) in
  let rec _layer_to_sound laylist = match laylist with
    | []                    -> ()
    | ((start,length),ss)::t   -> (
        let (s, l) = Time.overlap remix render_extent (start, length) in
        let (rs, rl) = Time.extent_to_raw_time remix (s, l) in
        if rl > 0 then (
          let raw_sound = (ss undersound) remix start (s, l) in
          FB.blit raw_sound 0 sound (rs - raw_render_start) rl);
        _layer_to_sound t) in
  _layer_to_sound layer.la_notes;
  sound;;