root/ocaml-remix/trunk/plugin.ml

type plugin = Sound.sound -> Sound.sound;;

let from_sound s = function _ -> s;;

exception InappropriatePlugin

let get_ports ladspa = 
  let ports = Ladspa_raw.port_count ladspa in
  let rec _portdesc n = 
    if n = ports then []
    else (n, Ladspa_raw.port_descriptor ladspa n)::_portdesc (n + 1) in
  _portdesc 0

let set_control_value plugin handle port value = 
  let v = Ladspa_raw.control_value_to_buffer value in
  Ladspa_raw.connect_port plugin handle port v;;

let ladspa_init func ladspa handle =
  let ports = get_ports ladspa in
  let inControlPorts = List.filter (function (a,(b,c)) -> 
    b = Ladspa_raw.Input && c = Ladspa_raw.Control) ports in
    List.iter (function p -> set_control_value ladspa handle p (func p)) 
          (List.map fst inControlPorts);
  let outControlPorts = List.filter (function (a,(b,c)) ->
    b = Ladspa_raw.Output && c = Ladspa_raw.Control) ports in
    List.iter (function p -> set_control_value ladspa handle p 0.0)
          (List.map fst outControlPorts);;

let from_ladspa_impl ladspa setup href insound remix extent render_extent =
  let build_handles _ = 
    let create_f _ = 
      let h = Ladspa_raw.instantiate ladspa (Remix.samplerate remix) in
      Ladspa_raw.activate ladspa h;
      setup ladspa h; h in
    Array.init (Remix.channels remix) create_f in
  let raw_start, raw_length = Time.extent_to_raw_time remix render_extent in
  let handles = (match !href with
    | None -> 
      (
        let h = build_handles () in
        href := Some (h, raw_start + raw_length);
        h
      )
    | Some (h, t) -> 
      (
        if t = raw_start 
        then (
          href := Some (h, t + raw_length);
          h
        ) else (
          let h = build_handles () in
          href := Some (h, raw_start + raw_length);
          h
        )
      )) in
  let ports = get_ports ladspa in
  let inAudioPorts = List.filter (function (a,(b,c)) -> 
        b = Ladspa_raw.Input && c = Ladspa_raw.Audio) ports in
  let outAudioPorts = List.filter (function (a,(b,c)) -> 
        b = Ladspa_raw.Output && c = Ladspa_raw.Audio) ports in
  let num_in = List.length inAudioPorts in
  let num_out = List.length outAudioPorts in 
  let create_in_buffers n sound length =
    let b = Array.init n (function _ -> Ladspa_raw.empty_buffer length) in
    Ladspa_raw.raw_sound_to_buffers sound b length; b in
  let create_out_buffers n length = 
    Array.init n (function _ -> Ladspa_raw.empty_buffer length) in
  let connect portlist portpos h b i =
    Ladspa_raw.connect_port ladspa h.(i) (fst (List.nth portlist portpos)) 
              b.(i) in
  if num_in = 1 && num_out = 1 then (
    let raw_insound = insound remix extent render_extent in
    let channels = Remix.channels remix in
    let buffers = create_in_buffers channels raw_insound raw_length in
    let outbuffers = create_out_buffers channels raw_length in
    for i = 0 to (channels - 1) do (
      connect inAudioPorts 0 handles buffers i;
      connect outAudioPorts 0 handles outbuffers i;
      Ladspa_raw.run ladspa handles.(i) raw_length
    ) done;
    Ladspa_raw.buffers_to_raw_sound outbuffers raw_length
  ) else if num_in = 0 && num_out = 1 then (
    let channels = Remix.channels remix in
    let outbuffers = create_out_buffers channels raw_length in
    for i = 0 to (channels - 1) do (
      connect outAudioPorts 0 handles outbuffers i;
      Ladspa_raw.run ladspa handles.(i) raw_length
    ) done;
    Ladspa_raw.buffers_to_raw_sound outbuffers raw_length
  ) else raise InappropriatePlugin;;

let from_ladspa ladspa setup = 
  let href = ref None in
  from_ladspa_impl ladspa setup href;;