root/ocaml-remix/trunk/sound.ml

(* a raw sound is an array of int values *)
type raw_sound = FB.buffer;;

(* but sounds have a start, a rendered start, and a rendered length *)
type sound = Remix.remix -> Time.time -> Time.extent -> raw_sound;; 

let silence r e (s,l) =
  let length = Time.time_to_raw_time r l in
  FB.create length (Remix.channels r);;

(* note: length applies to raw sounds *)
let length = FB.length;;

let size = FB.size;;

(* note: ignore start time when writing raw sounds *)
let write_raw_sound r out snd =
  IO.nwrite out "RIFF";
  IO.write_i32 out ((size snd) * 2 + 36);
  IO.nwrite out "WAVE";
  IO.nwrite out "fmt "; (* format chunk *)
  IO.write_i32 out 16;
  IO.write_i16 out 1; (* no compression *)
  IO.write_i16 out (Remix.channels r);
  IO.write_i32 out (Remix.samplerate r);
  IO.write_i32 out ((Remix.samplerate r) * (Remix.channels r) * 2);
  IO.write_i16 out ((Remix.channels r) * 2); (* bytes per frame *)
  IO.write_i16 out 16; (* bits per sample - always 16 *)
  IO.nwrite out "data"; (* data chunk *)
  IO.write_i32 out ((size snd) * 2);
  for i = 0 to (size snd - 1) do IO.write_i16 out (FB.short_at snd i) done;;

let write output remix snd start render_extent =
  let raw_sound = snd remix start render_extent in
  write_raw_sound remix output raw_sound;; 

let preview remix sound start (rstart,rlength) =
  let raw_start = Time.time_to_raw_time remix rstart in
  let raw_inc = Time.time_to_raw_time remix (Time.Seconds 0.2) in
  let dev = Oss.sound_open () in
  Oss.sound_set_parms dev (Remix.channels remix) (Remix.samplerate remix); 
  let t = ref raw_start in
  let cond = 
    (
      if rlength = Time.Forever 
      then (fun a -> true)
      else (
        let raw_length = Time.time_to_raw_time remix rlength in
        fun a -> a < raw_length
      )
    ) in
  while cond !t do (
    Oss.sound_write dev 
        (sound remix start (Time.Samples !t, Time.Samples raw_inc));
    t := !t + raw_inc) done;
  Oss.sound_close dev;;

let raw_preview remix sound = 
  let dev = Oss.sound_open () in
  Oss.sound_set_parms dev (Remix.channels remix) (Remix.samplerate remix);
  Oss.sound_write dev sound;
  Oss.sound_close dev;;