root/ocaml-remix/trunk/time.ml

(* raw time is in samples *)
type raw_time = int;;

(* time is specified by the user in a number of possible formats *)
type time =   Seconds of float 
            | Samples of int 
            | Beats of float 
            | Hertz of float
            | Forever ;;

type raw_extent = raw_time * raw_time;;

(* an extent is a start and a length *)
type extent = time * time;;

exception ButHowLongIsForever;;

let time_to_raw_time r t = 
  let sec_to_sam s = int_of_float (s *. (float_of_int (Remix.samplerate r))) in
  match t with
  | Seconds f -> sec_to_sam f
  | Samples i -> i
  | Beats   f -> sec_to_sam (f /. (Remix.bpm r) *. 60.)
  | Hertz   f -> sec_to_sam (1. /. f)
  | Forever   -> raise ButHowLongIsForever;;

let time_to_raw_samples r t = time_to_raw_time r t * Remix.channels r;;

let extent_to_raw_time r (s,l) =
  (time_to_raw_time r s, time_to_raw_time r l);;

let extent_to_raw_samples r (s,l) = 
  (time_to_raw_samples r s, time_to_raw_samples r l);;

let t_max r a b = Samples (max (time_to_raw_time r a) (time_to_raw_time r b));;
let t_min r a b = Samples (min (time_to_raw_time r a) (time_to_raw_time r b));;
let t_add r a b = 
  if a = Forever || b = Forever then Forever else 
  Samples ((time_to_raw_time r a) + (time_to_raw_time r b));;
let t_sub r a b = 
  if a = Forever then Forever else
  Samples ((time_to_raw_time r a) - (time_to_raw_time r b));;

let overlap r (astart, alen) (bstart, blen) =
  let (s, e) =
    let start = t_max r astart bstart in 
    if alen = Forever then (start, t_add r bstart blen)
    else if blen = Forever then (start, t_add r astart alen)
    else (start, t_min r (t_add r astart alen) (t_add r bstart blen)) in
  (s, t_sub r e s)

let to_string time =
  match time with
  | Seconds s -> Printf.sprintf "%f seconds" s
  | Samples s -> Printf.sprintf "%d samples" s
  | Beats   b -> Printf.sprintf "%f beats"   b
  | Hertz   h -> Printf.sprintf "%f Hz"      h
  | Forever   -> Printf.sprintf "Forever!"