root/ocaml-remix/trunk/wave.ml

type wave = Volume.volume -> float -> Sound.sound;;

(* generator amplitude period start time *)
type generator = float -> float -> int -> int -> float;;

exception AmplitudeTooHigh;;

(* these waves are phased globally so that clicks don't occur between
   adjacent sounds.  Hence we don't need to worry about the extent
   of the sound, only the rendered extent *)
let sin_generator amp period start time =
  let stime = time + start in
  let coef = (float_of_int stime) *. 3.142 *. 2. in
  amp *. (sin (coef /. period));; 

let square_generator amp period start time =
  if mod_float (float_of_int (time + start)) period < period/.2. 
  then amp else 0.0;;

let tri_generator amp period start time =
  let stime = time + start in
    (mod_float (float_of_int stime) period) /. period *. amp;;

let generate generator volume rate remix ss (start, length) = 
  let raw_length = Time.time_to_raw_time remix length in
  let raw_start = Time.time_to_raw_time remix start in
  let raw_ss = Time.time_to_raw_time remix ss in
  let period = float_of_int (Remix.samplerate remix) /. rate in
  let offset = (raw_start - raw_ss) in
  let channels = Remix.channels remix in
  let vfunc = fun p -> Volume.amplitude remix volume (p + offset) in
  let buffer = FB.create raw_length channels in
  FB.fill buffer (fun p -> generator (vfunc p) period raw_start p);
  buffer;;

let sin = generate sin_generator;;
let square = generate square_generator;;
let tri = generate tri_generator;;